Копия статьи "Формулы вычисляемых полей". URL: https://msdn.microsoft.com/ru-ru/library/bb862071(v=office.12).aspx
Формулы условия
Можно использовать следующие формулы для тестирования условия оператора и возврата значения "Да" или "Нет", тестирования альтернативного значения, такого как "ОК" или "Есть проблемы", или для возврата пробела или тире для представления пустого значения (Null).
Определение того, больше одно число, чем другое, или меньше
Чтобы выполнить это сравнение, используйте функцию ЕСЛИ
| Столбец1 | Столбец2 | Формула | Описание (возможный результат) |
|---|---|---|---|
|
15000 |
9000 |
=[Столбец1]>[Столбец2] |
Столбец1 больше, чем Столбец2? (Да) |
|
15000 |
9000 |
=ЕСЛИ([Столбец1]<=[Столбец2], "ОК", "Есть проблемы") |
Столбец1 меньше, чем Столбец2, или равен ему? (Есть проблемы) |
Возвращение логического значения после сравнения содержимого столбцов
Для результатов, являющихся логическим значением ("Да" или "Нет"), используйте функции И, ИЛИ и НЕТ.
| Столбец1 | Столбец2 | Столбец3 | Формула | Описание (возможный результат) |
|---|---|---|---|---|
|
15 |
9 |
8 |
=И([Столбец1]>[Столбец2], [Столбец1]<[Столбец3]) |
15 больше, чем 9, и меньше, чем 8? (Нет) |
|
15 |
9 |
8 |
=ИЛИ([Столбец1]>[Столбец2], [Столбец1]<[Столбец3]) |
15 больше, чем 9, или меньше, чем 8? (Да) |
|
15 |
9 |
8 |
=НЕТ([Столбец1]+[Столбец2]=24) |
15 плюс 9 не равно 24? (Нет) |
Для результатов, являющихся другим вычислением, или любым другим значением, отличным от "Да" или "Нет", используйте функции "ЕСЛИ", "И" и "ИЛИ".
| Столбец1 | Столбец2 | Столбец3 | Формула | Описание (возможный результат) |
|---|---|---|---|---|
|
15 |
9 |
8 |
=ЕСЛИ([Столбец1]=15, "ОК", "Есть проблемы") |
Если значение в Столбец1 равно 15, верните "ОК". (ОК) |
|
15 |
9 |
8 |
=ЕСЛИ([Столбец1]>[Столбец2], [Столбец1]<[Столбец3]). "ОК", "Есть проблемы") |
Если 15 больше, чем 9, и меньше, чем 8, верните "ОК". (Есть проблемы) |
|
15 |
9 |
8 |
=ЕСЛИ(ИЛИ([Столбец1]>[Столбец2], [Столбец1]<[Столбец3]). "ОК", "Есть проблемы") |
Если 15 больше, чем 9, или меньше, чем 8, верните "ОК". (ОК) |
Отображение нулей как пробелов или тире
Для отображения нуля используйте простые вычисления. Для отображения пробела или тире используйте функцию "ЕСЛИ".
| Столбец1 | Столбец2 | Формула | Описание (возможный результат) |
|---|---|---|---|
|
10 |
10 |
=[Столбец1]-[Столбец2] |
Второе число вычтено из первого. (0) |
|
15 |
9 |
=ЕСЛИ([Столбец1]-[Столбец2],"-", [Столбец1]-[Столбец2]) |
Возвращает тире, когда значением является ноль. (-) |
Скрытие ошибочных значений в столбцах
Для отображения тире, #Н/Д или НД в месте ошибки используйте функцию ЕОШИБКА.
| Столбец1 | Столбец2 | Формула | Описание (возможный результат) |
|---|---|---|---|
|
10 |
0 |
=[Столбец1]/[Столбец2] |
Приводит к ошибке (#Деление/0) |
|
10 |
0 |
=ЕСЛИ(ЕОШИБКА([Столбец1]/[Столбец2],"НД", [Столбец1]/[Столбец2]) |
Возвращает НД, если значение является ошибкой |
|
10 |
0 |
=ЕСЛИ(ЕОШИБКА([Столбец1]/[Столбец2],"-", [Столбец1]/[Столбец2]) |
Возвращает тире, если значение является ошибкой |
Формулы даты и времени
Можно использовать следующие формулы для выполнения вычислений, основанных на датах и времени, таких как добавление дней, месяцев или лет к дате, вычисление разницы между двумя датами и преобразование времени в десятичное значение.
Добавление дат
Чтобы добавить дни к дате, используйте оператор добавления (+).
 Примечание |
|---|
|
При работе с датами для типа возвращаемого значения вычисленного столбца следует установить "Дата" и "Время". |
| Столбец1 | Столбец2 | Формула | Описание (возможный результат) |
|---|---|---|---|
|
6.9.2007 |
3 |
=[Столбец1]+[Столбец2] |
Добавляет 3 дня к 6.9.2007 (6.12.2007) |
|
12.10.2008 |
54 |
=[Столбец1]+[Столбец2] |
Добавляет 54 дня к 12.10.2008 (2.2.2009) |
Чтобы добавить месяцы к дате, используйте функции ДАТА, ГОД, МЕСЯЦ или ДЕНЬ.
| Столбец1 | Столбец2 | Формула | Описание (возможный результат) |
|---|---|---|---|
|
6.9.2007 |
3 |
=ДАТА(ГОД([Столбец1]),МЕСЯЦ([Столбец1])+[Столбец2],ДЕНЬ([Столбец1])) |
Добавляет 3 месяца к 6.9.2007 (9.9.2007) |
|
12.10.2008 |
25 |
=ДАТА(ГОД([Столбец1]),МЕСЯЦ([Столбец1])+[Столбец2],ДЕНЬ([Столбец1])) |
Добавляет 25 месяцев к 12.10.2008 (1.10.2011) |
Чтобы добавить годы к дате, используйте функции ДАТА, ГОД, МЕСЯЦ или ДЕНЬ.
| Столбец1 | Столбец2 | Формула | Описание (возможный результат) |
|---|---|---|---|
|
6.9.2007 |
3 |
=ДАТА(ГОД([Столбец1])+[Столбец2],МЕСЯЦ([Столбец1]),ДЕНЬ([Столбец1])) |
Добавляет 3 года к 6.9.2007 (6.9.2010) |
|
12.10.2008 |
25 |
=ДАТА(ГОД([Столбец1])+[Столбец2],МЕСЯЦ([Столбец1]),ДЕНЬ([Столбец1])) |
Добавляет 25 лет к 12.10.2008 (12.10.2033) |
Чтобы добавить сочетание дней, месяцев и лет к дате, используйте функции ДАТА, ГОД, МЕСЯЦ и ДЕНЬ.
| Столбец1 | Формула | Описание (возможный результат) |
|---|---|---|
|
6.9.2007 |
=ДАТА(ГОД([Столбец1])+3,МЕСЯЦ([Столбец1])+1,ДЕНЬ([Столбец1])+5) |
Добавляет 3 года, 1 месяц и 5 дней к 6.9.2007 (7.14.2010) |
|
12.10.2008 |
=ДАТА(ГОД([Столбец1])+1,МЕСЯЦ([Столбец1])+7,ДЕНЬ([Столбец1])+5) |
Добавляет 1 год, 7 месяцев и 5 дней к 12.10.2008 (7.15.2010) |
Вычисление разницы между двумя датами
Для выполнения этого вычисления используйте функцию РАЗНДАТ.
| Столбец1 | Столбец2 | Формула | Описание (возможный результат) |
|---|---|---|---|
|
01-янв-1995 |
15-янв-1999 |
=РАЗНДАТ([Столбец1], [Столбец2],"д") |
Возвращает число дней между двумя датами (1626) |
|
01-янв-1995 |
15-янв-1999 |
=РАЗНДАТ([Столбец1], [Столбец2],"гм") |
Возвращает число месяцев между датами, пропуская год (5) |
|
01-янв-1995 |
15-янв-1999 |
=РАЗНДАТ([Столбец1], [Столбец2],"гд") |
Возвращает число дней между датами, пропуская год (165) |
Вычисление разницы между двумя значениями времени
Чтобы представить результат в стандартном формате времени (часы:минуты:секунды), используйте оператор вычитания (-) и функцию ТЕКСТ. Чтобы этот метод работал, значение часов не должно превышать 24, а значение минут и секунд — значение 60.
| Столбец1 | Столбец2 | Формула | Описание (возможный результат) |
|---|---|---|---|
|
06.09.2007 10:35 |
06.09.2007 15:30 |
=ТЕКСТ([Столбец2]-[Столбец1],"ч") |
Часов между двумя значениями времени (4) |
|
06.09.2007 10:35 |
06.09.2007 15:30 |
=ТЕКСТ([Столбец2]-[Столбец1],"ч:мм") |
Часов и минут между двумя значениями времени (4:55) |
|
06.09.2007 10:35 |
06.09.2007 15:30 |
=ТЕКСТ([Столбец2]-[Столбец1],"ч:мм:сс") |
Часов, минут и секунд между двумя значениями времени (04:55:00) |
Чтобы представить общий результат с использованием одной единицы времени, используйте функцию ЦЕЛОЕ или функцию ЧАС, МИНУТА или СЕКУНДА.
| Столбец1 | Столбец2 | Формула | Описание (возможный результат) |
|---|---|---|---|
|
06.09.2007 10:35 |
06.10.2007 15:30 |
=ЦЕЛОЕ(([Столбец2]-[Столбец1])*24) |
Всего часов между двумя значениями времени (28) |
|
06.09.2007 10:35 |
06.10.2007 15:30 |
=ЦЕЛОЕ(([Столбец2]-[Столбец1])*1440) |
Всего минут между двумя значениями времени (1735) |
|
06.09.2007 10:35 |
06.10.2007 15:30 |
=ЦЕЛОЕ(([Столбец2]-[Столбец1])*86400) |
Всего секунд между двумя значениями времени (104100) |
|
06.09.2007 10:35 |
06.10.2007 15:30 |
=ЧАС(([Столбец2]-[Столбец1])*24) |
Часов между двумя значениями времени, если разность не превышает 24 (4) |
|
06.09.2007 10:35 |
06.10.2007 15:30 |
=МИНУТА(([Столбец2]-[Столбец1]) |
Минут между двумя значениями времени, если разность не превышает 60 (55) |
|
06.09.2007 10:35 |
06.10.2007 15:30 |
=СЕКУНДА(([Столбец2]-[Столбец1]) |
Секунд между двумя значениями времени, если разность не превышает 60 (0) |
Преобразование времени
Чтобы преобразовать часы из стандартного формата времени в десятичное число, используйте функцию ЦЕЛОЕ.
| Столбец1 | Формула | Описание (возможный результат) |
|---|---|---|
|
10:35 |
=([Столбец1]-ЦЕЛОЕ([Столбец1]))*24 |
Количество часов, начиная с 12:00 (10,583333) |
|
12:15 |
=([Столбец1]-ЦЕЛОЕ([Столбец1]))*24 |
Количество часов, начиная с 12:00 (12,25) |
Чтобы преобразовать часы из десятичного числа в стандартный формат времени (часы:минуты:секунды), используйте оператор деления и функцию ТЕКСТ.
| Столбец1 | Формула | Описание (возможный результат) |
|---|---|---|
|
23:58 |
=ТЕКСТ(Столбец1/24, "чч:мм:сс") |
Часов, минут и секунд, начиная с 12:00 (00:59:55) |
|
2:06 |
=ТЕКСТ(Столбец1/24, "ч:мм") |
Часов и минут, начиная с 12:00 (0:05) |
Вставка дат в юлианском представлении даты
Дата в юлианском представлении — это формат дат, состоящий из текущего года и числа дней от начала года. Например, дата 1 января 2007 года будет представлена как 2007001, а дата 31 декабря 2007 года как 2007365. Этот формат не основан на юлианском календаре.
Чтобы преобразовать дату в юлианское представление дат, используйте функции ТЕКСТ и ДАТАЗНАЧ.
| Столбец1 | Формула | Описание (возможный результат) |
|---|---|---|
|
6.23.2007 |
=ТЕКСТ([Столбец1],"гг")&ТЕКСТ(([Столбец1]-ДАТАЗНАЧ("1/1/"& ТЕКСТ([Столбец1],"гг"))+1),"000") |
Дата в юлианском формате с двузначным представлением года (07174) |
|
6.23.2007 |
=ТЕКСТ([Столбец1],"гггг")&ТЕКСТ(([Столбец1]-ДАТАЗНАЧ("1/1/"&ТЕКСТ([Столбец1],"гг"))+1),"000") |
Дата в юлианском формате с четырехзначным представлением года (2007174) |
Чтобы преобразовать дату в юлианское представление дат, которое используется в астрономии, используйте константу 2415018.50. Эта формула работает только для дат после 3.1.1901 и если используется система дат 1900.
| Столбец1 | Формула | Описание (возможный результат) |
|---|---|---|
|
6.23.2007 |
=[Столбец1]+2415018.50 |
Дата в юлианском формате, используемом в астрономии (2454274.50) |
Отображение дат как дней недели
Чтобы преобразовать даты в названия дней недели, используйте функции ТЕКСТ и ДЕНЬНЕД.
| Столбец1 | Формула | Описание (возможный результат) |
|---|---|---|
|
19-фев-2007 |
=ТЕКСТ(ДЕНЬНЕД([Столбец1]), "дддд") |
Вычисляет день недели для даты и возвращает полное имя дня (понедельник) |
|
3-янв-2008 |
=ТЕКСТ(ДЕНЬНЕД([Столбец1]), "ддд") |
Вычисляет день недели для даты и возвращает сокращенное имя дня (Пн) |
Математические формулы
Можно использовать следующие формулы для различных математических вычислений, таких как сложение, вычитание, умножение и деление чисел; вычисление среднего или медианы чисел; округление чисел и подсчет количества значений.
Сложение чисел
Чтобы сложить числа в строке в двух или нескольких столбцах, используйте оператор сложения (+) или функцию СУММ.
| Столбец1 | Столбец2 | Столбец3 | Формула | Описание (возможный результат) |
|---|---|---|---|---|
|
6 |
5 |
4 |
=[Столбец1]+[Столбец2]+[Столбец3] |
Складывает значения в первых трех столбцах (15) |
|
6 |
5 |
4 |
=СУММ[Столбец1],[Столбец2],[Столбец3] |
Складывает значения в первых трех столбцах (15) |
|
6 |
5 |
4 |
=СУММ(ЕСЛИ([Столбец1]>[Столбец2], [Столбец1]-[Столбец2], 10), [Столбец3]) |
Если значение в Столбец1 больше, чем в Столбец2, прибавляет разность и значение в Столбец3. Также прибавляет 10 и значение в Столбец3 (5) |
Вычитание чисел
Чтобы вычесть числа в строке в двух или нескольких столбцах, используйте оператор вычитания (-) или функцию СУММ с отрицательными числами.
| Столбец1 | Столбец2 | Столбец3 | Формула | Описание (возможный результат) |
|---|---|---|---|---|
|
15000 |
9000 |
-8000 |
=[Столбец1]-[Столбец2] |
Вычитает 9000 из 15000 (6000) |
|
15000 |
9000 |
-8000 |
=СУММ[Столбец1],[Столбец2],[Столбец3] |
Складывает числа в первых трех столбцах, включая отрицательные значения (16000) |
Вычисление разности между двумя числами в виде процентного соотношения
Используйте операторы вычитания (-) и деления (/) и функцию АБС.
| Столбец1 | Столбец2 | Формула | Описание (возможный результат) |
|---|---|---|---|
|
2342 |
2500 |
=([Столбец2]-[Столбец])/АБС([Столбец1]) |
Изменение процентного соотношения (6,75% или 0,06746) |
Умножение чисел
Чтобы помножить числа в строке в двух или нескольких столбцах, используйте оператор умножения (*) или функцию ПРОИЗВЕД.
| Столбец1 | Столбец2 | Формула | Описание (возможный результат) |
|---|---|---|---|
|
5 |
2 |
=[Столбец1]*[Столбец2] |
Умножает числа в первых двух столбцах (10) |
|
5 |
2 |
=ПРОИЗВЕД([Столбец1], [Столбец2]) |
Умножает числа в первых двух столбцах (10) |
|
5 |
2 |
=ПРОИЗВЕД([Столбец1],[Столбец2],2) |
Умножает числа в первых двух столбцах, а также число 2 (20) |
Деление чисел
Чтобы разделить числа в строке в двух или нескольких столбцах, используйте оператор деления (/).
| Столбец1 | Столбец2 | Формула | Описание (возможный результат) |
|---|---|---|---|
|
15000 |
12 |
=[Столбец1]/[Столбец2] |
Делит 15000 на 12 (1250) |
|
15000 |
12 |
=([Столбец1]+10000)/[Столбец2] |
Складывает 15000 и 10000 и затем делит сумму на 12 (2083) |
Вычисление среднего чисел
Среднее также называют средней величиной. Чтобы вычислить среднее чисел в строке в двух или нескольких столбцах, используйте функцию СРЗНАЧ.
| Столбец1 | Столбец2 | Столбец3 | Формула | Описание (возможный результат) |
|---|---|---|---|---|
|
6 |
5 |
4 |
=СРЗНАЧ([Столбец1],[Столбец2],[Столбец3]) |
Среднее чисел в первых трех столбцах (5) |
|
6 |
5 |
4 |
=СРЗНАЧ(ЕСЛИ([Столбец1]>[Столбец2], [Столбец1]-[Столбец2], 10), [Столбец3]) |
Если значение в Столбец1 больше, чем в Столбец2, вычисляет среднее разности значения в Столбец3. Также вычисляет среднее значения 10 и Столбец3 (2,5) |
Вычисление медианы чисел
Медина это значение в центре упорядоченного диапазона чисел. Чтобы вычислить медиану группы чисел, используйте функцию МЕДИАНА.
| A | B | C | D | E | F | Формула | Описание (результат) |
|---|---|---|---|---|---|---|---|
|
10 |
7 |
9 |
27 |
0 |
4 |
=МЕДИАНА(A, B, C, D, E, F) |
Медиана чисел в первых 6 столбцах (8) |
Вычисление наименьшего и наибольшего числа в диапазоне
Чтобы вычислить наименьшее и наибольшее число в строке в двух или нескольких столбцах, используйте функции МИН и МАКС.
| Столбец1 | Столбец2 | Столбец3 | Формула | Описание (возможный результат) |
|---|---|---|---|---|
|
10 |
7 |
9 |
=МИН([Столбец1], [Столбец2], [Столбец3]) |
Наименьшее число (7) |
|
10 |
7 |
9 |
=МАКС([Столбец1], [Столбец2], [Столбец3]) |
Наибольшее число (10) |
Количество значений
Чтобы подсчитать количество значений, используйте функцию СЧЕТ.
| Столбец1 | Столбец2 | Столбец3 | Формула | Описание (возможный результат) |
|---|---|---|---|---|
|
Яблоко |
12.12.2007 |
=СЧЕТ([Столбец1], [Столбец2], [Столбец3]) |
Подсчитывает число столбцов, которые содержат числовые значения. Исключает дату и время, текст и пустые значения (Null) (0) |
|
|
$12 |
#Деление/0! |
1,01 |
=СЧЕТ([Столбец1], [Столбец2], [Столбец3]) |
Подсчитывает число столбцов, которые содержат числовые значения, но исключает ошибки и логические значения (2) |
Увеличение или уменьшение числа в процентном отношении
Для выполнения этого вычисления используйте оператор процентов (%).
| Столбец1 | Столбец2 | Формула | Описание (возможный результат) |
|---|---|---|---|
|
23 |
3% |
=[Столбец1]*(1+5%) |
Увеличивает число в Столбец1 на 5% (24,15) |
|
23 |
3% |
=[Столбец1]*(1+[Столбец2]) |
Увеличивает число в Столбец1 соответственно значению процента в Столбец2: 3% (23,69) |
|
23 |
3% |
=[Столбец1]*(1-[Столбец2]) |
Уменьшает число в Столбец1 соответственно значению процента в Столбец2: 3% (22,31) |
Возведение числа в степень
Для выполнения этого вычисления используйте оператор возведения в степень (^) или функцию СТЕПЕНЬ.
| Столбец1 | Столбец2 | Формула | Описание (возможный результат) |
|---|---|---|---|
|
5 |
2 |
=[Столбец1]^[Столбец2] |
Вычисляет пять в квадрате (25) |
|
5 |
3 |
=СТЕПЕНЬ([Столбец1], [Столбец2]) |
Вычисляет пять в кубе (125) |
Округление числа
Чтобы округлить число, используйте функцию ОКРУГЛВВЕРХ, НЕЧЁТ или ЧЁТН.
| Столбец1 | Формула | Описание (возможный результат) |
|---|---|---|
|
20,3 |
=ОКРУГЛВВЕРХ([Столбец1],0) |
Округляет 20,3 до ближайшего большего целого числа (21) |
|
-5,9 |
=ОКРУГЛВВЕРХ([Столбец1],0) |
Округляет -5,9 до ближайшего большего целого числа (-5) |
|
12,5493 |
=ОКРУГЛВВЕРХ([Столбец1],2) |
Округляет 12,5493 до ближайшей большей сотой части с двумя десятичными знаками (12,55) |
|
20,3 |
=ЧЁТН([Столбец1]) |
Округляет 20,3 до ближайшего большего четного числа (22) |
|
20,3 |
=НЕЧЁТ([Столбец1]) |
Округляет 20,3 до ближайшего большего нечетного числа (21) |
Для округления к меньшему числу используйте функцию ОКРУГЛВНИЗ.
| Столбец1 | Формула | Описание (возможный результат) |
|---|---|---|
|
20,3 |
=ОКРУГЛВНИЗ([Столбец1],0) |
Округляет 20,3 до ближайшего меньшего числа (20) |
|
-5,9 |
=ОКРУГЛВНИЗ([Столбец1],0) |
Округляет -5,9 до ближайшего меньшего целого числа (-6) |
|
12,5493 |
=ОКРУГЛВНИЗ([Столбец1],2) |
Округляет 12,5493 до ближайшей меньшей сотой части с двумя десятичными знаками (12,54) |
Чтобы округлить число до ближайшего меньшего числа или дроби, используйте функцию ОКРУГЛ.
| Столбец1 | Формула | Описание (возможный результат) |
|---|---|---|
|
20,3 |
=ОКРУГЛ([Столбец1],0) |
Округляет 20,3 в меньшую сторону, так как дробная часть меньше, чем 0,5 (20) |
|
5,9 |
=ОКРУГЛ([Столбец1],0) |
Округляет 5,9 в большую сторону, так как дробная часть больше, чем 0,5 (6) |
|
-5,9 |
=ОКРУГЛ([Столбец1],0) |
Округляет -5,9 в меньшую сторону, так как дробная часть меньше, чем -0,5 (-6) |
|
1,25 |
=ОКРУГЛ([Столбец1], 1) |
Округляет число до ближайшей десятой части (один десятичный знак). Так как округляемая часть равна 0,05 или больше, число округляется в большую сторону (результат: 1,3) |
|
30,452 |
=ОКРУГЛ([Столбец1], 2) |
Округляет число до ближайшей сотой части (два десятичных знака). Так как округляемая часть 0,002 меньше, чем 0,005, число округляется в меньшую сторону (результат: 30,45) |
Чтобы округлить число до значащей цифры больше 0, используйте функции ОКРУГЛ, ОКРУГЛВНИЗ, ОКРГУЛВВЕРХ, ЦЕЛОЕ и ДЛСТР.
| Столбец1 | Формула | Описание (возможный результат) |
|---|---|---|
|
5492820 |
=ОКРУГЛ([Столбец1],3-ДЛСТР(ЦЕЛОЕ([Столбец1]))) |
Округляет число до 3 значащих цифр (5490000) |
|
22230 |
=ОКРУГЛВНИЗ([Столбец1],3-ДЛСТР(ЦЕЛОЕ([Столбец1]))) |
Округляет нижнее число вниз до 3 значащих цифр (22200) |
|
5492820 |
=ОКРУГЛВВЕРХ([Столбец1], 5-ДЛСТР(ЦЕЛОЕ([Столбец1]))) |
Округляет верхнее число вверх до 5 значащих цифр (5492900) |
Текстовые формулы
Можно использовать следующие формулы для управления текстом, например для сочетания или связывания значений из нескольких столбцов, сравнения содержимого столбцов, удаления знаков или пробелов и повтора знаков.
Изменение регистра текста
Чтобы изменить регистр текста, используйте функцию ПРОПИСН, СТРОЧН или ПРОПНАЧ.
| Столбец1 | Формула | Описание (возможный результат) |
|---|---|---|
|
нина Вайтцен |
=ПРОПИСН([Столбец1]) |
Задает верхний регистр текста (НИНА ВАЙТЦЕН) |
|
нина Вайтцен |
=СТРОЧН([Столбец1]) |
Задает нижний регистр текста (нина вайтцен) |
|
нина Вайтцен |
=ПРОПНАЧ([Столбец1]) |
Задает заглавные буквы в тексте (Нина Вайтцен) |
Объединение имени и фамилии
Чтобы объединить имя и фамилию, используйте оператор амперсанд (&) или функцию СЦЕПИТЬ.
| Столбец1 | Столбец2 | Формула | Описание (возможный результат) |
|---|---|---|---|
|
Карлос |
Карвалло |
=[Столбец1]&[Столбец2] |
Объединяет две строки (КарлосКарвалло) |
|
Карлос |
Карвалло |
=[Столбец1]&" "&[Столбец2] |
Объединяет две строки, разделенные пробелом (Карлос Карвалло) |
|
Карлос |
Карвалло |
=[Столбец2]&", "&[Столбец1] |
Объединяет две строки, разделенные запятой и пробелом (Карвалло, Карлос) |
|
Карлос |
Карвалло |
=СЦЕПИТЬ([Столбец2], ",", [Столбец1]) |
Объединяет две строки, разделенные запятой (Карвалло,Карлос) |
Объединение текста и чисел из разных столбцов
Чтобы объединить текст и числа, используйте функцию СЦЕПИТЬ, оператор амперсанд (&) или функцию ТЕКСТ и оператор амперсанд.
| Столбец1 | Столбец2 | Формула | Описание (возможный результат) |
|---|---|---|---|
|
Янг |
28 |
=[Столбец1]&" продал "&[Столбец2]&" единиц." |
Объединяет указанное выше содержимое в фразу (Янг продал 28 единиц.) |
|
Дюбуа |
40% |
=[Столбец1]&" продал "&ТЕКСТ([Столбец2],"0%")&" от всех продаж." |
Объединяет указанное выше содержимое в фразу (Дюбуа продал 40% от всех продаж.) Примечание Функция ТЕКСТ добавляет форматированное значение из Столбец2 вместо основного значения, которое равно 0,4. |
|
Янг |
28 |
=СЦЕПИТЬ([Столбец1]," продал ",[Столбец2]," единиц.") |
Объединяет указанное выше содержимое в фразу (Янг продал 28 единиц.) |
Объединение текста с датой или временем
Чтобы объединить текст с датой или временем, используйте функцию ТЕКСТ и оператор амперсанд (&).
| Столбец1 | Столбец2 | Формула | Описание (возможный результат) |
|---|---|---|---|
|
Дата выставления счета |
5-июн-2007 |
="Дата Выписки: "&ТЕКСТ([Столбец2], "д-мммм-гггг") |
Объединяет текст с датой (дата Выписки: 5-июн-2007) |
|
Дата выставления счета |
5-июн-2007 |
=[Столбец1]&" "&ТЕКСТ([Столбец2], "ммм-дд-гггг") |
Объединяет текст и дату из разных столбцов в одном столбце (Дата выставления счета Июн-05-2007) |
Сравнение содержимого столбцов
Чтобы сравнить один столбец с другим столбцом или списком значений, используйте функции СОВПАД и ИЛИ.
| Столбец1 | Столбец2 | Формула | Описание (возможный результат) |
|---|---|---|---|
|
BD122 |
BD123 |
=EXACT([Column1],[Column2]) |
Compares contents of first two columns (No) |
|
BD122 |
BD123 |
=СОВПАД([Столбец1], "BD122") |
Сравнивает содержимое в Столбец1 и строки "BD122" (Да) |
Определение того, соответствует ли значение столбца или его части отдельному тексту
Чтобы определить, соответствует ли значение столбца или его части отдельному тексту, используйте функции ЕСЛИ, НАЙТИ, ПОИСК и ЕЧИСЛО.
| Столбец1 | Формула | Описание (возможный результат) |
|---|---|---|
|
Вайтцен |
=ЕСЛИ([Столбец1]="Вайтцен", "ОК", "Есть проблемы") |
Определяет, является ли Столбец1 — Вайтцен (ОК) |
|
Вайтцен |
=ЕСЛИ(ЕЧИСЛО(НАЙТИ("в",[Столбец1])), "ОК", "Есть проблемы") |
Определяет, содержит ли Столбец1 букву "в" (ОК) |
|
BD123 |
=ЕЧИСЛО(НАЙТИ("BD",[Столбец1])) |
Определяет, содержит ли Столбец1 данные "BD" (Да) |
Подсчет непустых столбцов
Чтобы подсчитать количество непустых столбцов, используйте функцию СЧЁТЗ.
| Столбец1 | Столбец2 | Столбец3 | Формула | Описание (возможный результат) |
|---|---|---|---|---|
|
Продажи |
19 |
=СЧЁТЗ([Столбец1], [Столбец2]) |
Подсчитывает количество непустых столбцов (2) |
|
|
Продажи |
19 |
=СЧЁТЗ([Столбец1], [Столбец2], [Столбец3]) |
Подсчитывает количество непустых столбцов (2) |
Удаление знаков из текста
Чтобы удалить знаки из текста, используйте функции ДЛСТР, ЛЕВСИМВ и ПРАВСИМВ.
| Столбец1 | Формула | Описание (возможный результат) |
|---|---|---|
|
Витамин A |
=ЛЕВСИМВ([Столбец1],ДЛСТР([Столбец1])-2) |
Возвращает 7 (9-2) знаков, начиная слева (Витамин) |
|
Витамин B1 |
=ПРАВСИМВ([Столбец1],ДЛСТР([Столбец1])-8) |
Возвращает 2 (10-8) знаков, начиная справа (B1) |
Удаление пробелов из начального и конечного столбцов
Чтобы удалить пробелы из столбца, используйте функцию СЖПРОБЕЛЫ.
| Столбец1 | Формула | Описание (возможный результат) |
|---|---|---|
|
Привет, там! |
=СЖПРОБЕЛЫ([Столбец1]) |
Удаляет пробелы из начала и окончания (Привет, там!) |
Повтор знаков в столбце
Чтобы повторить знак в столбце, используйте функцию ПОВТОР.
| Формула | Описание (возможный результат) |
|---|---|
|
=ПОВТОР(".",3) |
Повторяет точку 3 раза (...) |
|
=ПОВТОР("-",10) |
Повторяет тире 10 раз (----------) |
